stazsoftware.com/www.stazsoftware.com.tar/www.stazsoftware.com/futurebasic/sample-code/DBFD.sit/DBFD2.0/DataBrowser With Toolbox/Simple DataBrowser

Text File | 2003-11-13 | 30KB | 897 lines

'~'A
'                       Runtime : Rntm Appearance.Incl
'                           CPU : Carbon
'                    CALL Req'd : Off
'~'B
'~Introduction
/*

     Simple DataBrowser demo is meant to give the basis for using and
     exploring the rich Carbon DataBrowser control.

     The demo will let the end-user select a folder and then will display
     its content in a DataBrowser control. Files and folders will be listed
     along with their icon.

     A DataBrowser is a Carbon control with which you will have a love or
     hate affair (depending on your success in mastering it); well, let's say
     the Apple documentation is a bit demanding on the topic.

     The DataBrowser is in itself a whole universe that certainly requires
     some time for the discovery. Anyway, if you're new to the thing, here
     is what you need to know to get you started. Be prepared to be amazed.

     The purpose of a DataBrowser control is to help in the navigation
     through information displayed in list view or column view. It also
     allows the end-user to edit that information. This particular control
     has a whole lot of features that can be implemented gradually:

       Ñ No limitation on the number of cells displayed in a list,
       Ñ Built-in drag-and-drop handling,
       Ñ Built-in display types for text, icons, checkboxes, pop-up menus,
         progress bars, relevance ranks, and sliders,
       Ñ Support for contextual menus and context-sensitive help
       Ñ Built-in text editing for cells displaying text, and
       Ñ Built-in hierarchical list support.

     The DataBrowser communicates with your program via a set of callback
     procedures, but to get the control to function, only one callback is
     mandatory. It is called with the barbaric name GetSetItemDataProc
     because the DataBrowser uses the same routine to request information
     about the data it must display or to inform your program that the
     end-user has modified an editable cell in the table. In the demo below
     we will not deal with user changes, we will just display information.

     The steps to put the pieces together are the following:

       Ñ Create a DataBrowser control in a window
       Ñ Install the callback procedures in the DataBrowser
       Ñ Configure the DataBrowser (adding columns)
       Ñ Add items in the DataBrowser (adding rows)
       Ñ Chat with the DataBrowser (displaying cells)

     This slightly differs from the creation of a button with the
     APPEARANCE BUTTON statement, but actually it is not much harder.

     Please use the popup menu button FN at the top left of this window
     and check the Unsorted item because I will refer to functions used
     in the demo that follows.

     The demo starts calling FN StartProgram which intalls a basic menu,
     opens a window, creates a DataBrowser control and enters the main
     event loop waiting for a menu choice.

'~Creating a DataBrowser Control

     The creation of the DataBrowser is extremely simple and realized with
     a single call to a Toolbox function:

     err = FN CreateDataBrowserControl( windowRef, bounds, _kDataBrowserListView, browser )

     On return the browser variable will be set with the Control Reference
     for the DataBrowser freshly created.

'~Installing the callback procedures

     Installing the callback procedures is somewhat a bit more complicated,
     but not that hard. You need first a record variable of the
     DataBrowserCallbacks type which contains 10 different fields, each one
     dedicated to a routine that will handle a specific task. You must first
     initialize the callbacks for your variable with a Toolbox function like
     so:

     err = FN InitDataBrowserCallbacks( myDataBrowserCallbacks )

     then, you set the appropriate fields of the record variable with your
     procedures that the DataBrowser will use to communicate with your program.
     Finally, you can install the callbacks in the DataBrowser like so:

     err = FN SetDataBrowserCallbacks( browser, myDataBrowserCallbacks )

     Here in the demo, we will use only one field to install the mandatory
     procedure (see how it is done in local fn InstallDataBrowserCallbacks)


'~Adding columns

     Once you have successfully created the DataBrowser control and installed
     the callbacks, you can setup the columns you want to display. In this demo,
     this is done at the LOCAL FN ConfigureDataBrowser. Since it is a bit
     cumbersome, but not difficult, to define a column, I have created two little
     functions to simplify the coding when you have a lot of columns to add.
     You must define all the column properties (including a unique identifier
     with which you can refer to that column later) and set also the style of its
     header. This is merely done setting the fields of an appropriate variable
     of type DataBrowserListViewColumnDesc before calling a Toolbox function
     like so:

     err = FN AddDataBrowserListViewColumn( browser, columnDescriptor, _kDataBrowserListViewAppendColumn )

     Note: the _kDataBrowserListViewAppendColumn constant is just a big number
     to make sure that the added column is appended and not inserted between
     two other columns.

'~Adding rows

     Adding row is actually adding items in the list maintained by the DataBrowser
     control. The added items are identifiers of type DataBrowserItemID (defined
     as an unsigned long integer). This is done in the demo below at the LOCAL FN
     AddOrClearDataBrowserItems, because the program is very simple and it needs
     only to add or delete all the items at once. Again, you use a specific
     Toolbox function like the following:

     err = FN AddDataBrowserItems( browser, 0, 1, itemID, 0 )

     To add multiple items at once:

     err = FN AddDataBrowserItems( browser, 0, numberOfItems, @arrayOfItemID(0), 0 )

     Removing items is equally simple:

     err = fn RemoveDataBrowserItems ( browser, 0, numberOfItems, @arrayOfItems(0) , 0 )

     Note: in the demo below, we use predefined constants, namely _kDataBrowserNoItem
     and _kDataBrowserItemNoProperty which both have the value 0.

'~Displaying cells

     Now you're almost ready to see your items on screen. But you need to know
     that the DataBrowser control will call the GetSetItemData procedure when
     it needs to display the info regarding an item, so that it can show
     the appropriate values in the cells of the table. In the demo below the
     entry point of the callback procedure is located at the end of the source
     code, but the procedure calls immediately the local function MyGetSetItemData,
     passing back the values it has received, so the actual work is done there.

     When the DataBrowser invokes your callback procedure it passes to your
     program a few parameters that tell what's going on. They tell you
     which DataBrowser is making the call, which itemID is concerned, which
     property is involved (let's say the column to simplify), a pointer to the
     data in the cell and finally a boolean value that indicates if the
     DataBrowser is making the call because it requests information from your
     program, or because it informs your program that the end-user of the
     application has changed the cell's contents and that it is time for you to
     accept or refuse the change. In the demo below, we will just answer the
     DataBrowser when it calls the program for the information it needs to
     display.
     The information you must give back to the DataBrowser depends on the
     column property, that is to say the type of data it must display in the
     cell. For example, if the cell displays a checkbox to represent the info,
     your program must send back a value to tell the DataBrowser if the button
     must be checked or unchecked for the concerned item.
     For each content type there is a specific call. In the case of a checkbox
     you would use a ThemeButtonValue (i.e. _kThemeButtonOff, _kThemeButtonOn
     or _kThemeButtonMixed ) along with the appropriate function:

// for checkbox
     err = fn SetDataBrowserItemDataButtonValue( itemData, ThemeButtonValue )
// for text
     err = fn SetDataBrowserItemDataText( itemData, CFStringRef )
// for icon
     err = fn SetDataBrowserItemDataIcon( itemData, IconRef )
// for popup menu
     err = fn SetDataBrowserItemDataMenuRef( itemData, MenuRef )
// for slider, relevance rank, progress bar, popup menuItem
     err = fn SetDataBrowserItemDataValue( itemData, LongIntegerValue )
// for date and time
     err = fn SetDataBrowserItemDataLongDateTime( itemData, LongDateTime )

     There is way much more things to know about the DataBrowser control,
     and I have not yet mentioned that the control can be customized,
     in fact, there's no less than a total of 17 callback procedures that
     you could install in the control, so the possibilities are endless,
     but now you can start to play with it when the principles are understood.


                                                      Alain   May 2003
*/
'~'6

/*
     Converted Apple header file for DataBrowser declarations
*/
Include "Tlbx ControlDefinitions.Incl"

/*
     We will use some functions located in those headers
*/
Include "Util_Files.incl"
Include "Tlbx Icons.Incl"

'~Toolbox Added Declarations
/*
     Missing Toolbox declarations from the FB header files
*/
_kWindowInWindowMenuAttribute  = (1 << 27 )
_kControlDataBrowserPart       = 24

Toolbox Fn SetAutomaticControlDragTrackingEnabledForWindow( WindowRef inWindow, Boolean inTracks) = OSStatus
Toolbox Fn CFAllocatorGetDefault = CFAllocatorRef

'~Application Constants

// window FB identifier
_mainWnd         = 1

// custom creator code and identifier for the BrowserData control
_myCreator       = _"DEMO"
_myDataBrowser   = _"Brsr"//

// custom identifier of the unique column we will use in the demo
_fileColumnID    = _"file"

_scrollBarWidth  = 16

// elementary menu identifiers
_menuFile = 1

Begin Enum 1
_itemOpenFolder
_
_itemQuit
End Enum

// to use with the AddOrClearDataBrowser FN
Begin Enum
_addItems
_clearItems
End Enum

'~Application Globals
/*
     Define a custom record holding the item information
     we are interested in. The itemID field will help us
     to synchronize with the list maintained by the DataBrowser.
     We will store the file items in a dynamic array of that
     type of record. In that demo, we could have used the index
     in the array as the itemID for the items.

     We will only display the name and the file icon,
     therefore only the spec field and the file type
     are required in the demo. The other fields are
     left here so that you could start playing adding
     columns.
*/
Begin Record ItemRecord
Dim itemID   As Long
Dim spec     As FSSpec
Dim type     As OSType
Dim creator  As OSType
Dim dataLen  As Long
Dim rsrcLen  As Long
Dim cDate    As Long
Dim mDate    As Long
Dim flags    As Short
Dim attrib   As Short
End Record

Begin Globals

Dim Dynamic       gFiles(_maxInt) As ItemRecord

End Globals

'~';
'~-
'~Utility Functions
/*
     Handy function that returns the maximum index in a dynamic array
*/
Def Fn UBound(@P As Ptr) = [P + _AutoXREFCurr] - 1

'~'1
/*
     This function returns the iconRef for a given file
*/
Clear Local Mode
Local Fn GetFileIcon( fSpec As .FSSpec, type As OSType )
'~'9
Dim @ iconH As IconRef
Dim @ label As Int
Dim   err   As OSErr

If fSpec Then err = Fn GetIconRefFromFile( #fSpec, iconH, label )
Long If err != _noErr Or iconH = _nil
Select type
Case _"APPL" : type = _kGenericApplicationIcon
Case _"fldr" : type = _kGenericFolderIcon
Case Else    : type = _kGenericDocumentIcon
End Select
err = Fn GetIconRef( _kOnAppropriateDisk, _kSystemIconsCreator, type, iconH )
End If

End Fn = iconH


'~--
'~Application Functions

'~'1
/*
     This function retrieves the browser reference from the window
     in which it is located.
     The browser reference has been saved has a window property.
     You can store private properties with user interface elements
     as your liking and retrieve them when you need them.
*/
Clear Local
Local Fn GetDataBrowserFromWindow( wRef As WindowRef )
'~'9

Dim As OSStatus     err
Dim As ControlRef @ browser

Long If wRef
err = Fn GetWindowProperty( wRef, _myCreator, _myDataBrowser, Sizeof(browser), #_nil, browser )
End If

End Fn = browser


'~'1
/*
     This function scans the folder specified by its FSSpec,
     and stores the item information found in our global
     dynamic array.
*/
Clear Local Fn CollectFileItems ( fSpec As .FSSpec )
'~'9

Dim As Short  Index
Dim           pb.128

#If Ndef _kFolderBit
_kFolderBit = 3
#Endif

Index = 1// start at index 1

Do

pb.ioFDirIndex%  = Index// fill the param block
pb.ioNamePtr&    = @fSpec.name// the folder requested
pb.ioVRefNum%    = fSpec.vRefNum
pb.ioDirID&      = fSpec.parID

If Fn PBGetCatInfoSync( pb ) Then Exit Do// get info on item and leave the loop on error

Long If ( pb.ioFlUsrWds.fdFlags% And _fInvisible ) = _false// skip invisible items
gFiles.itemID(Index) = Index// this index will become our DataBrowser itemID
gFiles.spec  (Index) = fSpec// save the item FSSpec

Long If Fn BitTst (pb.ioFlAttrib%, _kFolderBit)// Is it a folder?
 // it's a folder...
gFiles.type   (Index)  = _"fldr"// set the file type
gFiles.creator(Index)  = _"----"// set the creator code

Xelse// it is a file...

gFiles.type   (Index) = pb.ioFlUsrWds.fdType&// grab the info from the param block
gFiles.creator(Index) = pb.ioFlUsrWds.fdCreator&
gFiles.flags  (Index) = pb.ioFlUsrWds.fdFlags%
gFiles.dataLen(Index) = pb.ioFlLgLen&
gFiles.rsrcLen(Index) = pb.ioFlRLgLen&
gFiles.cDate  (Index) = pb.ioFlCrDat&
gFiles.mDate  (Index) = pb.ioFlMdDat&
gFiles.attrib (Index) = pb.ioFlAttrib%
End If

End If

index++// next file or folder in the current folder

Until _nil

End Fn



'~-----
'~DataBrowser Setting & Getting Data
'~'1
/*
     This function is called via a callback procedure. This is
     the only required routine to work with a DataBrowser control.
     The DataBrowser asks you to setup some values for the cells
     that it must display. Those values are set with specific functions
     depending on the type of the cell to be updated.
     With the same callback routine the DataBrowser may inform your
     program that a cell has been changed by the end user, so it is
     time to get the value sent by the DataBrowser to update your
     internal information.
*/
Clear Local Fn MyGetSetItemData( browser As ControlRef, itemID As DataBrowserItemID, columnPropID As DataBrowserPropertyID, itemData As DataBrowserItemDataRef, userChangedItemData As Boolean )
'~'9
Dim As OSStatus    err
Dim As CFStringRef txt
Dim As IconRef     iconH
Dim As FSSpec      fSpec : fSpec = gFiles.spec(itemID)// copy info from the dynamic array...
Dim As OSType      fType : fType = gFiles.type(itemID)// ... in local variables

err = _noErr

Long If userChangedItemData = _false

Select columnPropID// Which property has been requested by the DataBrowser

Case _fileColumnID' Names and icons for our unique column

iconH = Fn GetFileIcon( fSpec, ftype )// Retrieve the icon file
Long If iconH// and give back the IconRef to the DataBrowser
err = Fn SetDataBrowserItemDataIcon( itemData, iconH )
err = Fn ReleaseIconRef(iconH)
End If
// Create a CFSStringRef with the item filename and give it back to the DataBrowser
txt = Fn CFStringCreateWithPascalString( Fn CFAllocatorGetDefault, fSpec.name, _kCFStringEncodingMacRoman )
err = Fn SetDataBrowserItemDataText( itemData, txt ) : CFRelease( txt )

Case Else:

err = _errDataBrowserPropertyNotSupported

End Select

Xelse
/*
     The end user has altered the cell if we come here.
*/
err = _errDataBrowserPropertyNotSupported

End If

End Fn = err


/*
     This function is called to add or delete all the
     items in the DataBrowser control.
*/
Clear Local
Local Fn AddOrClearDataBrowserItems( whatToDo )
'~'9
Dim As ControlRef   browser
Dim As UInt32       i, @ tempItem, numberOfItems
Dim As OSStatus     err
Dim As Handle       itemsHandle
/*
     Get the browser reference from the window
*/
browser = Fn GetDataBrowserFromWindow( Window( _wndRef ) )
If browser == _nil Then Exit Fn
/*
     If we are adding items then we get the number of items
     from our dynamic array, if we want to delete, it is
     more polite to ask the DataBrowser how many items
     it has in store.
*/
Select whatToDo
Case _addItems   : numberOfItems = Fn UBound(gFiles)
Case _clearItems : err = Fn GetDataBrowserItemCount( browser, _kDataBrowserNoItem, _true, _nil, numberOfItems )
End Select

If numberOfItems = 0 Then Exit Fn
/*
     It is much more efficient to add or remove all
     the items at once. To do this, we need to have
     an array of itemIDs to pass onto the DataBrowser
     control along with the number of itemIDs in that
     array.
     We must then recreate or "fake" the array filling
     it with the itemIDs retrieved from our dynamic array
     of itemRecords.

     We will use a temporary handle for that purpose.
     The XREF@ statement will allow us to treat the
     allocated memory block like an array.
*/
Xref@ arrayOfItems(_maxInt) As DataBrowserItemID

arrayOfItems& = Fn NewHandle(numberOfItems * Sizeof(DataBrowserItemID) )
If arrayOfItems = _nil Then Exit Fn
/*
     WARNING:
     the code below will work because we have stored our
     itemIDs sequentially in the DataBrowser list. This is
     not a requirement, you can store any itemID value you
     like (except 0) in no particular order.

     Notice that our fake array of itemIDs starts at
     index 0, whereas our array of ItemRecords starts
     at index 1.
*/
For i = 1 To numberOfItems
arrayOfItems(i - 1) = gFiles.itemID(i)
Next

Select whatToDo
Case _clearItems : err = Fn RemoveDataBrowserItems ( browser,_kDataBrowserNoItem, numberOfItems, @arrayOfItems(0) , _kDataBrowserItemNoProperty )
Case _addItems   : err = Fn AddDataBrowserItems( browser, _kDataBrowserNoItem, numberOfItems, @arrayOfItems(0), _kDataBrowserItemNoProperty )
End Select

DisposeHandle(arrayOfItems&)// Get rid of the memory used by our temporary handle

err = Fn SetDataBrowserScrollPosition ( browser, 0, 0 )// reset the scroll bar position

End Fn


'~-------
'~DataBrowser Installing
'~';
/*
     This function creates the DataBrowser. It will
     size the DataBrowser control to match the content
     area of the window, then remove the automatic
     focus ring of the DataBrowser.
*/
Clear Local Fn CreateDataBrowser( wRef As WindowRef )
'~'9

Dim As Rect         r
Dim As ControlRef @ browser
Dim As Boolean    @ frameAndFocus

Long If Fn GetWindowBounds( wRef, _kWindowContentRgn, r ) = _noErr
OffsetRect( r, -r.left, -r.top )
Long If Fn CreateDataBrowserControl( wRef, r, _kDataBrowserListView, browser ) = _noErr
// Turn off DB's focus frame
Long If Fn SetControlData( browser, _kControlNoPart, _kControlDataBrowserIncludesFrameAndFocusTag, Sizeof(frameAndFocus), frameAndFocus )
End If
End If
End If

End Fn = browser


/*
     The two functions below are supposed to simplify
     the code, allowing to avoid cumbersome statements
*/
'~'1
/*
     After creating the DataBrowser, you need to configure it.
     That is to say to define columns and their properties.
     Here are the column property types you can use:

          constant names                 cell's contents are set with
     _kDataBrowserCustomType        No associated data (must use custom callbacks)
     _kDataBrowserIconType          IconRef, IconTransformType, RGBColor
     _kDataBrowserTextType          CFStringRef
     _kDataBrowserDateTimeType      DateTime or LongDateTime
     _kDataBrowserSliderType        Min, Max, Value
     _kDataBrowserCheckboxType      ThemeButtonValue
     _kDataBrowserProgressBarType   Min, Max, Value
     _kDataBrowserRelevanceRankType Min, Max, Value
     _kDataBrowserPopupMenuType     MenuRef, Value
     _kDataBrowserIconAndTextType   IconRef, CFStringRef, etc

*/
Clear Local Mode
Local Fn SetupColumn(        column As .DataBrowserListViewColumnDesc, ┬
                        columnID As UInt32, ┬
                  columnProperty As DataBrowserPropertyType, ┬
                     columnTitle As Str255, ┬
                     columnFlags As DataBrowserPropertyFlags, ┬
                   headerContent As SInt16, ┬
                        minWidth As UInt16, ┬
                        maxWidth As UInt16 )
'~'1

column.propertyDesc.propertyID    = columnID
column.propertyDesc.propertyType  = columnProperty
column.propertyDesc.propertyFlags = columnFlags

column.headerBtnDesc.btnContentInfo.contentType = headerContent
column.headerBtnDesc.minimumWidth               = minWidth
column.headerBtnDesc.maximumWidth               = maxWidth
column.headerBtnDesc.titleString = Fn CFStringCreateWithPascalString( Fn CFAllocatorGetDefault, columnTitle, _kCFStringEncodingMacRoman )

End Fn

'~'9
/*
     SetupColumnHeaderStyle( column, font, size, face, mode,just )

     column     : a column descriptor

     font       : font ID used in the header button or the old contants:
                    _sysfont    _london       _times
                    _applfont   _athens       _helvetica
                    _newyork    _sanfran      _courier
                    _geneva     _toronto      _symbol
                    _monaco     _cairo        _mobile
                    _venice     _losangeles   _apfontid

     size      : font size in pixels

     face      : font style. Use the following constants:
                    _boldBit%    _ulineBit%    _shadowBit%
                    _italicBit%  _outlineBit%  _condenseBit%

     mode      : transfer mode. Try:
                    _srcCopy       _notSrcCopy  _patCopy  _notPatCopy
                    _srcOr         _notSrcOr    _patOr    _notPatOr
                    _srcXor        _notSrcXor   _patXor   _notPatXor
                    _srcBic        _notSrcBic   _patBic   _notPatBic
                    _hilite        _blend
                    _addPin        _addOver
                    _subPin        _addMax
                    _adMax         _subOver
                    _adMin         _ditherCopy
                    _transparent   _grayishTextOr
                    _hilitetransfermode

     just     : text justification. Use:
                    _teJustLeft     _teFlushDefault
                    _teJustCenter   _teCenter
                    _teJustRight    _teFlushRight
                    _teForceLeft    _teFlushLeft
*/

Clear Local Mode
Local Fn SetupColumnHeaderStyle( column As ^DataBrowserListViewColumnDesc, ┬
                               font As Short, ┬
                               size As Short, ┬
                               face As Short, ┬
                               mode As Short, ┬
                               just As Short )
'~'1
Dim colStyle As ControlFontStyleRec

colStyle = column.headerBtnDesc.btnFontStyle
If font Then colStyle.flags = colStyle.flags Or _kControlUseFontMask : colStyle.font  = font
If size Then colStyle.flags = colStyle.flags Or _kControlUseSizeMask : colStyle.size  = size
If face Then colStyle.flags = colStyle.flags Or _kControlUseFaceMask : colStyle.style = face
If mode Then colStyle.flags = colStyle.flags Or _kControlUseModeMask : colStyle.Mode  = mode
If just Then colStyle.flags = colStyle.flags Or _kControlUseJustMask : colStyle.just  = just
call BlockMoveData( @colStyle, @column.headerBtnDesc.btnFontStyle, Sizeof(ControlFontStyleRec) )

End Fn

/*
     This function will add a single column in the DataBrowser control
*/
Clear Local Fn ConfigureDataBrowser( browser As ControlRef )
'~'9
Dim As OSStatus                       err
Dim As DataBrowserListViewColumnDesc  col
Dim As DataBrowserViewStyle         @ viewStyle

err = Fn GetDataBrowserViewStyle( browser, viewStyle )

Select viewStyle

Case _kDataBrowserListView:

col.headerBtnDesc.titleOffset = 0
col.headerBtnDesc.version     = _kDataBrowserListViewLatestHeaderDesc

// ------- Add the name & icon column -------
/*
     Custom function for easy setup

     FN SetupColumn( columnDescriptor,┬
                             columnID, ┬
                       columnProperty, ┬
                          columnTitle, ┬
                          columnFlags, ┬
                        headerContent, ┬
                             minWidth, ┬
                             maxWidth )
*/

Fn SetupColumn(          col, ┬
               _fileColumnID, ┬
_kDataBrowserIconAndTextType, ┬
                       "Name",┬
_kDataBrowserListViewSelectionColumn_kDataBrowserListViewDefaultColumnFlags, ┬
    _kControlContentTextOnly, ┬
                      0 ,280 )
/*
     Custom function for easy setup

     FN SetupColumnHeaderStyle( columnDescriptor, fontID, textSize, textFace, textMode,justification )
*/

Fn SetupColumnHeaderStyle( col, 0, 0, 0, 0, _teFlushDefault )
err = Fn AddDataBrowserListViewColumn( browser, col, _kDataBrowserListViewAppendColumn )

Case _kDataBrowserColumnView:

End Select

End Fn


'~';
/*
     This function sets the callback procedure that the
     DataBrowser will use to communicate with the program.
     There is a bunch of callback routines available
     for customization of the DataBrowser. Here, we use the
     only one which is required to display data.
*/
Clear Local Fn InstallDataBrowserCallbacks( browser As ControlRef )
'~'9

Dim As OSStatus               err
Dim As DataBrowserCallbacks @ myCallbacks

myCallbacks.version = _kDataBrowserLatestCallbacks//Use latest layout and callback signatures

err = Fn InitDataBrowserCallbacks( myCallbacks )
myCallbacks.u.itemDataCallback  = Fn NewDataBrowserItemDataUPP ( [Proc "GetSetItemDataProc"  + _FBprocToProcPtrOffset] )
err = Fn SetDataBrowserCallbacks( browser, myCallbacks )

End Fn


'~';
/*
     This function will resize the DataBrowser when needed,
     for example, when the window is resized.
*/
Clear Local Fn RefreshDataBrowser( wNum As Long )
'~'9

Dim As Rect         r
Dim As ControlRef   browser
Dim As WindowRef  @ wRef

Get Window wNum, wRef// retrieve the WindowRef from the FB Window number
Long If wRef
Long If Fn GetWindowBounds( wRef, _kWindowContentRgn, r ) = _noErr
browser = Fn GetDataBrowserFromWindow( wRef )
Long If browser
SizeControl( browser, r.right - r.left, r.bottom - r.top)
End If
End If
End If

End Fn


'~';
'~----
'~Event Handling
'~'1
/*
    This function is called via our cheap menu.
*/
Clear Local Fn doOpenFolder
'~'9

Dim As Int    err
Dim As FSSpec fSpec
Dim As Str255 name

Long If Len( Files$( _FSSpecFolder, "Choose a folder",,fSpec ) )// select folder dialog
Fn AddOrClearDataBrowserItems( _clearItems )// not cancelled, so clear the current DataBrowser's items
Kill Dynamic gFiles// dispose of the current dynamic array
Fn CollectFileItems( fSpec )// collect files and folders
Compress Dynamic gFiles// optimize memory
Fn AddOrClearDataBrowserItems( _addItems )// create the DataBrowser items with the grabbed info
err = Usr FSGetFolderName( fSpec, name )// retrieve the folder name since folder FSSpecs have an empty name
Window _mainWnd, name// update window title
End If

End Fn


/*
     No risk of indigestion with that menu
*/
Local Fn doMenu
'~'9

Dim As Short menuID, itemID

menuID = Menu( _menuID )
itemID = Menu( _ItemID )

Select menuID
Case _menuFile
Select itemID
Case _itemOpenFolder : Fn doOpenFolder
Case _itemQuit       : End
End Select
End Select

Menu

End Fn


/*
     Minimalist dialog handler
*/
Local Fn doDialog
'~'9
Dim As Long act, ref

act = Dialog(0)
ref = Dialog(act)

Select act
Case _wndZoomIn, _wndZoomOut,_wndResized
Fn RefreshDataBrowser( ref )
Case _wndClose : End
End Select

End Fn

'~';
'~------
'~Program starts here
'~';
/*
     This function installs our cheap menu, a window
     and a DataBrowser control in that window.
     It runs the main event loop too.
*/
Clear Local Fn StartProgram
'~'9
Dim As OSStatus        err
Dim As Rect            r
Dim As WindowRef     @ wRef
Dim As ControlRef    @ browser

// Setup a menu
Menu _menuFile, 0              , _enable, "File"
Menu _menuFile, _itemOpenFolder, _enable, "Open Folder/O"
Menu _menuFile, _itemQuit      , _enable, "Quit/Q"

// Setup a window
SetRect( r, 100, 100, 600, 400 )
Appearance Window - _mainWnd, "Simple DataBrowser", @r ,_kDocumentWindowClass, ┬
                    _kWindowInWindowMenuAttribute _kWindowStandardDocumentAttributes

wRef = Window( _wndRef )// Get the WindowRef of that window
err  = Fn SetAutomaticControlDragTrackingEnabledForWindow( wRef, _true )

// Create the DataBrowser control
browser = Fn CreateDataBrowser( wRef )
Long If browser
Fn InstallDataBrowserCallbacks( browser )// Install the callback routines
Fn ConfigureDataBrowser( browser )// Configure the DataBrowser
err = Fn SetKeyboardFocus( wRef, browser, _kControlDataBrowserPart )// Set the keyboard focus
err = Fn SetWindowProperty( wRef, _myCreator, _myDataBrowser, Sizeof(browser), browser )// Store our custom DataBrowser ID as a window property
End If

Window _mainWnd// Make the window visible

On Menu   Fn doMenu
On Dialog Fn doDialog

Do
Handleevents
Until _nil

End Fn

// The start
Fn StartProgram

'~---
'~Applications Proc
/*
     Entry point for the callback procedure
*/
#If Def _FBUseDebugger
Troff
#Endif

Goto "skip procs"

"GetSetItemDataProc"
Enterproc Fn GetSetItemDataProc( browser As ControlRef, itemID As DataBrowserItemID, prop As DataBrowserPropertyID, itemData As DataBrowserItemDataRef, changeValue As Boolean ) = OSStatus
Exitproc = Fn MyGetSetItemData( browser, itemID, prop, itemData, changeValue )

"skip procs"

#If Def _FBUseDebugger
Tron
#Endif